登录  
 加关注
查看详情
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

为梦飞翔

我希望我身边的亲人和朋友天天快乐!

 
 
 

日志

 
 

横向系数的计算实例  

2010-03-26 21:49:16|  分类: Ansys |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

    根据实际桥梁资料来求解横向分布系数,因为研究的桥梁是铰接板桥,板和板之间是用铰缝连结的,铰缝只传递剪力不传递弯矩,所以在模拟时把板与板之间的转动放松,此计算的铰缝是用刚性链杆模拟的,它的J节点转动全部放松(这符合桥梁实际).

    横向分布系数是根据某块板跨中弯矩和同一时刻全桥跨中弯距之和的比值来求得,也可以用某块板的跨中变形和同一时刻全桥跨中变形之和的比值得到,两者差距很小.

下为具体的建模命令流:

/BATCH                                                !批处理(便于多个截面的建模)
*create,section,mac
/prep7
et,1,plane82

rectng,0,0.99,0,0.6
cyl4,0.27,0.26,0.19,-180
cyl4,0.27,0.34,0.19,180
rectng,0.08,0.46,0.26,0.34 
/pnum,area,1                                         !显示面积编号
/replot

agen,2,2,4,1,0.45,0,0,100                     !对面积进行复制生成两个孔  
/replot
asel,s,,,2,7,1 
cm,ar,area                                             !将选择的面组成一个组件ar 
allsel 
asba,1,ar                                               !用第一个面减去组件ar
asel,all
esize,0.1  
amesh,all  
secwrite,kxb,sect,,1                               !写入截面1,名称kxb,后缀sect
sectype,1,beam,mesh,                          !定义截面1用于梁,mesh表示用户定义的划分网格
secoffset,cent,,,  
secread,'kxb','sect',,mesh                     !读出截面kxb

secplot,1,1
asel,all
aclear,all                                               !清除所有面单元网格
adel,all,,,1                                             !清除所有面和面上附着的线,关键点等等
finish
*end                                                      !结束批处理


finish
/clear
/filename,hxfbxs
section.mac

/prep7
/title,hengxiang fenbu xishu
 
et,1,beam44                                          !定义空心板单元
et,2,beam44                                          !定义刚性链杆

keyopt,2,8,111                                       !定义J端转动全部放松
 
mp,ex,1,3.3e10                                      !定义空心板材料属性             
mp,prxy,1,0.1667 
mp,dens,1,2600

mp,ex,2,3e16                                     !定义刚性链杆材料属性
mp,prxy,2,0.1667
mp,dens,2,0


r,2,1e-3,1,1,0.03,0.03                        !定义刚性链杆的实常数

n,1,0,0,0  
n,21,0,0,12.6  
fill
n,22,0,1,0 
ngen,9,100,1,22,1,1,0,0


type,1
mat,1
secnum,1
*do,i,1,20,1                                                  !生成180个空心板单元
 *do,k,1,9,1
   e,(k-1)*100+i,(k-1)*100+i+1,(k-1)*100+22
 *enddo
*enddo

esel,s,,,1,180,1
cm,t2,elem 
allsel
 
type,2 
mat,2  
real,2
*do,i,1,21,1                                            !生成168个刚性链杆单元
*do,k,1,8,1
 e,(k-1)*100+i,k*100+i  
*enddo 
*enddo
 
esel,s,,,181,348,1 
cm,t4,elem
 
*do,i,0,8,1                                           !选择梁的端点进行约束(简支)
allsel 
nsel,s,loc,z,0 
nsel,r,loc,y,0 
nsel,r,loc,x,i 
d,all,ux,,,,,uy,uz,rotz,roty
allsel 
nsel,s,loc,z,12.6  
nsel,r,loc,y,0 
nsel,r,loc,x,i 
d,all,ux,,,,,uy,rotz,roty  
allsel 
*enddo 

/solu
*do,i,0,8,1                                   !循环改变加载点,使单位力沿中跨横向移动
time,i+1
fdele,all,all  
nsel,s,loc,z,6.3
nsel,r,loc,x,i 
nsel,r,loc,y,0 
f,all,fy,-1                                     !删除前一个循环的集中力,否则就累加了
allsel 
solve  
*enddo

 

finish
/POST26
/axlab,x,time(s)
/axlab,y,displacementz(m)         !定义控制点
nsol,2,11,u,y,n11
nsol,3,111,u,y,n111
nsol,4,211,u,y,n211
nsol,5,311,u,y,n311
nsol,6,411,u,y,n411

nsol,7,511,u,y,n511
nsol,8,611,u,y,n611
nsol,9,711,u,y,n711

  
plvar,2,3,4,5,6,7,8,9

 

  评论这张
 
阅读(406)| 评论(0)

历史上的今天

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2018