登录  
 加关注
查看详情
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

为梦飞翔

我希望我身边的亲人和朋友天天快乐!

 
 
 

日志

 
 

三跨变截面连续梁桥  

2010-03-30 22:08:30|  分类: Ansys |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

fini
/clear
/title,three span continous bridge
/prep7
!上顶板的关键点位置(0m处)
k,1,0,0
k,2,-2.1
k,3,-2.6,-0.125
k,4,-2.8,-0.125
k,5,-3.0,-0.125
k,6,-3.4857,-0.1036
k,7,-3.9714,-0.0821
k,8,-4.4571,-0.0607
k,9,-4.9429,-0.0393
k,10,-5.4286,-0.0179
k,11,-5.9143,0.0036
k,12,-6.4,0.025

!下底板的关键点位置
k,13,-2.8,-1.85
k,14,,-1.85

!上顶板关键点49m位置
kgen,9,1,12,1,0,0,49/8,100

!上顶板关键点50m位置
kgen,2,1,12,1,0,0,50,900

!上顶板关键点50+34.5m位置
kgen,9,901,912,1,0,0,34.5/8,100

!上顶板关键点50+35m位置
kgen,2,901,912,1,0,0,35,900

!板的高度由1.85m变至3.875m
c1=0.000843399               !49m边跨的二次抛物线系数
c2=0.001701323               !34.5m边跨的二次抛物线系数

*dim,x1,array,8              !定义边跨的八分点位置
*do,i,1,8,1
  x1(i)=i*49/8
*enddo

*dim,x2,array,8              !定义中跨的八分点位置
*do,i,1,8,1
  x2(i)=i*34.5/8
*enddo

!下底板边跨(49m)八分点关键点的y坐标位置
*dim,yb,array,8             
*do,i,1,8,1
  yb(i)=c1*x1(i)**2
*enddo

!下底板中跨(34.5m)八分点关键点的y坐标位置
*dim,ym,array,8             
*do,i,1,8,1
  ym(i)=-c2*(x2(i)-34.5)**2+2.025
*enddo

!生成下底边跨(50m)八分点的关键点
*do,i,1,8,1
  kgen,2,13,14,1,0,-yb(i),x1(i),i*100
*enddo

!下底板50m处关键点
kgen,2,813,814,1,0,0,1,100

!生成下底中跨(50+34.5m)八分点的关键点
*do,i,1,8,1
  kgen,2,913,914,1,0,ym(i),x2(i),i*100
*enddo

!边墩处的横隔板位置(1,2,3,4~14为0m处横隔板位置的所有关键点,51,52,53~54为-0.5m处横隔板位置的所有关键点)
kgen,2,1,14,1,0,,-0.5,50


!中墩处的横隔板位置(801,802,803,804~814为49m处横隔板位置的所有关键点,901,902,903~904为50m处横隔板位置的所有关键点)

!生成板面

!上顶板,板厚0.25m
et,1,shell63
mp,dens,1,2500
mp,ex,1,3.5e10
mp,prxy,1,0.1667
r,1,0.25

*do,i,0,16,1
 a,1+i*100,1+(i+1)*100,2+(i+1)*100,2+i*100
*enddo
a,1,51,52,2
aatt,1,1,1
asel,none

!上顶板的加腋,板厚0.375m
r,2,0.375
*do,i,0,16,1
 a,2+i*100,2+(i+1)*100,3+(i+1)*100,3+i*100
*enddo
a,2,52,53,3
aatt,1,2,1
asel,none

!肋板与翼缘交接处,板厚0.5m
r,3,0.5
*do,i,0,16,1
 a,3+i*100,3+(i+1)*100,4+(i+1)*100,4+i*100
 a,4+i*100,4+(i+1)*100,5+(i+1)*100,5+i*100
*enddo
a,3,53,54,4
a,4,54,55,5
aatt,1,3,1
asel,none

!翼缘厚度渐变

!下面定义翼缘板的渐变厚度
*dim,hd,array,9
hd(9)=0.2
hd(8)=1*(3.4/7)*0.3/3.4+0.2
hd(7)=2*(3.4/7)*0.3/3.4+0.2
hd(6)=3*(3.4/7)*0.3/3.4+0.2
hd(5)=4*(3.4/7)*0.3/3.4+0.2
hd(4)=5*(3.4/7)*0.3/3.4+0.2
hd(3)=6*(3.4/7)*0.3/3.4+0.2
hd(2)=7*(3.4/7)*0.3/3.4+0.2
hd(1)=0.5

*do,i,1,8,1
 r,30+i,hd(i),hd(i),hd(i+1),hd(i+1)   !定义渐变的翼缘厚度
*enddo

*do,i,0,16,1
 *do,k,5,11,1
  a,k,k+50,k+1+50,k+1
  a,k+i*100,k+(i+1)*100,k+1+(i+1)*100,k+1+i*100
  aatt,1,k+26,1
  asel,none  
 *enddo
*enddo
asel,none

!肋板厚度0.5m
r,4,0.5
*do,i,0,16,1
  a,4+i*100,4+(i+1)*100,13+(i+1)*100,13+i*100
*enddo
a,4,54,63,13
aatt,1,4,1
asel,none

!下底板厚度0.25m~0.4m按2次抛物线过度
c3=6.2474e-05   !边跨(49m)底板厚度变化的二次抛物线系数
c4=0.000126024  !中跨(34.5m)底板厚度变化的二次抛物线系数

*dim,h1,array,8  !边跨底板厚度
*do,i,1,8,1
  h1(i)=0.25+c3*x1(i)**2
*enddo

*dim,h2,array,9  !中跨底板厚度
*do,i,1,8,1
  h2(i)=0.25+c4*x2(i)**2
*enddo
h2(9)=0.4

!生成边跨的底板单元
*do,i,1,8,1
  r,10+i,h1(i)
  a,13+(i-1)*100,13+i*100,14+i*100,14+(i-1)*100
  aatt,1,10+i,1
  asel,none
*enddo

!生成中跨的底板单元
*do,i,1,9,1
  r,20+i,h2(i)
  a,13+(i+7)*100,13+(i+8)*100,14+(i+8)*100,14+(i+7)*100
  aatt,1,20+i,1
  asel,none
*enddo

r,50,2   !横隔板厚度2m
a,1,51,64,14   !端横隔板
a,801,901,914,814
aatt,1,50,1

allsel
esize,0.4                  !定义单元尺寸
mshape,0                 !以四边形划分单元

mshkey,1                 !映射划分网格
amesh,all                   

nsel,all
nsym,x,10000,all
esym,x,10000,all


local,11,0,,,84.5            !定义局部坐标
csys,11
allsel
nsym,z,100000,all
esym,z,100000,all

allsel
nummrg,all
numcmp,all
csys,0               !恢复整体坐标系

!施加支座约束
!支座位置选择在肋板处(端部支座)
nsel,s,loc,y,-1.85
nsel,r,loc,x,-3,-2.6
nsel,r,loc,z,-0.5,0
d,all,ux,,,,,uy,roty,rotz

allsel
nsel,s,loc,y,-1.85
nsel,r,loc,x,2.6,3
nsel,r,loc,z,-0.5,0
d,all,ux,,,,,uy,roty,rotz


allsel
nsel,s,loc,y,-1.85
nsel,r,loc,x,-3,-2.6
nsel,r,loc,z,169,169.5
d,all,ux,,,,,uy,roty,rotz

allsel
nsel,s,loc,y,-1.85
nsel,r,loc,x,2.6,3
nsel,r,loc,z,169,169.5
d,all,ux,,,,,uy,roty,rotz

!中部支座
allsel
nsel,s,loc,y,-3.875
nsel,r,loc,x,2.6,3
nsel,r,loc,z,49,50
d,all,ux,,,,,uy,roty,rotz

allsel
nsel,s,loc,y,-3.875
nsel,r,loc,x,-3,-2.6
nsel,r,loc,z,49,50
d,all,ux,,,,,uy,roty,rotz

allsel
nsel,s,loc,y,-3.875
nsel,r,loc,x,-3,-2.6
nsel,r,loc,z,119,120
d,all,ux,,,,,uy,uz,roty,rotz

allsel
nsel,s,loc,y,-3.875
nsel,r,loc,x,2.6,3
nsel,r,loc,z,119,120
d,all,ux,,,,,uy,uz,roty,rotz

allsel 
eplot  
/color,elem,red
/eshape,1,0
/efacet,1  
/light,all,,1,100,0,2000,0,


!工况1  一期恒载
allsel
/solu
acel,,9.8
solve
fini

/post1
plnsol,s,1
nsel,s,loc,z,10
esln,s,,all
plnsol,s,1

  评论这张
 
阅读(750)| 评论(0)

历史上的今天

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2018