登录  
 加关注
查看详情
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

为梦飞翔

我希望我身边的亲人和朋友天天快乐!

 
 
 

日志

 
 

连续钢构施工分析  

2010-04-23 18:14:44|  分类: Ansys |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

建模过程
(1)根据横断面和纵断面进行建模
(2)通过关键点沿抛物线复制来组成小体积,再将小体积粘合
(3)用工作平面切分实体,切出预应力钢筋位置
(4)将钢筋选出分别赋予每个施工阶段特性
(5)将体选出赋予每个施工阶段特性
(6)将钢筋直线划分单元
(7)将体划分单元
(8)将每一阶段选出,定义成组
(9)根据施工阶段,分别杀死不需要的单元
(10)分析各个施工阶段的应力及其内力变化
本例来自《Algor、Ansys在桥梁工程中的应用方法与实例》
finish
/clear
/prep7
/title,the analysis of ganggou bridge
et,1,solid95
et,2,link8

mp,dens,1,2600
mp,ex,1,3.5e10
mp,prxy,1,0.1667

mp,dens,2,7800
mp,ex,2,1.95e11
mp,prxy,2,0.3

!直径15.24mm,标准强度1860MPa,单根张拉控制吨位195.5kN
areagjx=1.4e-4              !单根面积
*dim,gjarea,array,4         !定义各钢束面积
gjarea(1)=15*areagjx
gjarea(2)=18*areagjx
gjarea(3)=20*areagjx
gjarea(4)=22*areagjx

F=195.5e3               !每根钢绞线张拉控制吨位195.5kN
E=1.95e11               !钢绞线弹模
L=1                     !每根钢绞线长1m
detL=F*L/(E*areagjx)    !每根钢绞线单元的伸长量
istrn=detL/(detL+L)     !每根钢绞线单元的的拉应变
r,2,gjarea(1),istrn     !定义各种钢束的实常数
r,3,gjarea(2),istrn
r,4,gjarea(3),istrn
r,5,gjarea(4),istrn
acel,,9.8

!建立横断面关键点
k,2,-2.45,0
k,3,-3.25,0
k,4,-6,0
k,5,-6,-0.18
k,6,-3.25,-0.45
k,7,-2.45,-0.45
k,11,-3.25,-3.9
k,12,-2.45,-3.9
k,13,-2.45,-4.5
k,14,-3.25,-4.5

!进行关键点的对称复制(按抛物线复制以便生成体)
ksym,x,2,14,1,100

kgen,2,9,14,1,0,-0.00125*(40-10)*(40-10)+2,10,2000             !确定底板位置
kgen,2,109,114,1,0,-0.00125*(40-10)*(40-10)+2,10,2000
kgen,2,9,14,1,0,-0.00125*(40-20)*(40-20)+2,20,3000
kgen,2,109,114,1,0,-0.00125*(40-20)*(40-20)+2,20,3000
kgen,2,9,14,1,0,-0.00125*(40-30)*(40-30)+2,30,4000
kgen,2,109,114,1,0,-0.00125*(40-30)*(40-30)+2,30,4000
kgen,2,9,14,1,0,-0.00125*(40-40)*(40-40)+2,40,5000
kgen,2,109,114,1,0,-0.00125*(40-40)*(40-40)+2,40,5000

kgen,2,2,14,1,0,0,1,1000                                     !确定顶板位置
kgen,2,102,114,1,0,0,1,1000
kgen,2,2,7,1,0,0,10,2000
kgen,2,102,107,1,0,0,10,2000
kgen,2,2,7,1,0,0,20,3000
kgen,2,102,107,1,0,0,20,3000
kgen,2,2,7,1,0,0,30,4000
kgen,2,102,107,1,0,0,30,4000
kgen,2,2,7,1,0,0,40,5000
kgen,2,102,107,1,0,0,40,5000


!进行对称轴的定义
k,100,0,0,0
k,200,1,0,0
k,300,0,1,0
!进行拉伸路径的定义
k,400,0,-4.5,0                      !用来生成墩的拉伸路径
k,500,0,-14.5,0
l,400,500                           !生成墩的拉伸路径      

!定义3个剪切面,用来切分体积产生钢筋的分布平面
k,21,-3.75,-0.25,-40
k,22,3.75,-0.25,-40
k,23,3.75,-0.25,40
k,24,-3.75,-0.25,40
k,25,-6,-0.1,-40
k,26,-3.75,-0.25,-40
k,27,-3.75,-0.25,40
k,28,-6,-0.1,40
k,29,6,-0.1,-40
k,30,3.75,-0.25,-40
k,31,3.75,-0.25,40
k,32,6,-0.1,40


a,21,22,23,24       !用这3个面切割实体以产生钢束直线
a,25,26,27,28
a,29,30,31,32

*do,i,1000,5000,1000   !循环生成各个阶段的小体积
v,2+i-1000,i-1000+7,i-1000+107,i-1000+102,2+i,7+i,107+i,102+i
v,2+i-1000,i-1000+3,i-1000+6,i-1000+7,2+i,3+i,6+i,7+i
v,3+i-1000,i-1000+4,i-1000+5,i-1000+6,3+i,4+i,5+i,6+i
v,7+i-1000,i-1000+6,i-1000+11,i-1000+12,7+i,6+i,11+i,12+i
v,11+i-1000,i-1000+14,i-1000+13,i-1000+12,11+i,14+i,13+i,12+i
v,12+i-1000,i-1000+13,i-1000+113,i-1000+112,12+i,13+i,113+i,112+i
v,100+2+i-1000,100+i-1000+3,100+i-1000+6,100+i-1000+7,100+2+i,100+3+i,100+6+i,100+7+i
v,100+3+i-1000,100+i-1000+4,100+i-1000+5,100+i-1000+6,100+3+i,100+4+i,100+5+i,100+6+i
v,100+7+i-1000,100+i-1000+6,100+i-1000+11,100+i-1000+12,100+7+i,100+6+i,100+11+i,100+12+i
v,100+11+i-1000,100+i-1000+14,100+i-1000+13,100+i-1000+12,100+11+i,100+14+i,100+13+i,100+12+i
*enddo

!实心部分定义          !此处将0#块模拟为实心
v,7,12,112,107,1007,1012,1112,1107
!体的镜像复制
cskp,100,0,100,200,300               !定义工作坐标系100
vsel,all                             
csys,100                             !激活定义工作坐标系100  
vsymm,z,1,100,1,10000,0,0  
csys,0                               !恢复原来的坐标系

asel,s,loc,y,-4.5                    !选择0号块底面来拉伸成墩实体
vdrag,all,,,,,,1                     !沿着定义好的路径1拉伸
allsel


!生成各个钢筋位置
vsel,all
wprota,,,90        !将工作坐标系绕y轴旋转90°

!钢筋S1
wpave,2.7         !移动工作平面
Vsbw,all          !用工作平面去切分所有实体
wpave,3
vsbw,all
wpave,-3
vsbw,all
wpave,-2.7
vsbw,all

!钢筋S2
wpave,2.45
vsbw,all
wpave,3.25
vsbw,all
wpave,-3.25
vsbw,all
wpave,-2.45
vsbw,all

!钢筋S3
wpave,2.2
vsbw,all
wpave,3.5
vsbw,all
wpave,-3.5
vsbw,all
wpave,-2.2
vsbw,all

!钢筋S4
wpave,1.95
vsbw,all
wpave,3.75
vsbw,all
wpave,-3.75
vsbw,all
wpave,-1.95
vsbw,all

vsel,s,loc,y,-0.45,0       !选择所有的上顶板实体(切分出上顶板钢筋)
vsba,all,1           !用所定义的平面去切分所选实体
vsba,all,2
vsba,all,3

wpstyl       !关闭工作平面显示

allsel
vglue,all
vatt,1,1,1

         !选择并定义各个阶段各根钢筋的材料属性

lsel,s,loc,z,-10,10         !选择1号块上的钢筋
lsel,r,loc,y,-0.25
lsel,r,loc,x,2.7
cm,gj1_1,line
latt,2,2,2
allsel
lsel,s,loc,z,-10,10
lsel,r,loc,y,-0.25
lsel,r,loc,x,3
cm,gj1_2,line
latt,2,2,2
allsel
lsel,s,loc,z,-10,10
lsel,r,loc,y,-0.25
lsel,r,loc,x,-3
cm,gj1_3,line
latt,2,2,2
allsel
lsel,s,loc,z,-10,10
lsel,r,loc,y,-0.25
lsel,r,loc,x,-2.7
cm,gj1_4,line
latt,2,2,2
allsel                       !选择2#块上的钢筋
lsel,s,loc,z,-20,20
lsel,r,loc,y,-0.25
lsel,r,loc,x,2.45
cm,gj2_1,line
latt,2,3,2
allsel
lsel,s,loc,z,-20,20
lsel,r,loc,y,-0.25
lsel,r,loc,x,3.25
cm,gj2_2,line
latt,2,3,2
lsel,s,loc,z,-20,20
lsel,r,loc,y,-0.25
lsel,r,loc,x,-3.25
cm,gj2_3,line
latt,2,3,2
lsel,s,loc,z,-20,20
lsel,r,loc,y,-0.25
lsel,r,loc,x,-2.45
cm,gj2_4,line
latt,2,3,2
allsel                       !选择3#块上的钢筋
lsel,s,loc,z,-30,30
lsel,r,loc,y,-0.25
lsel,r,loc,x,2.2
cm,gj3_1,line
latt,2,4,2
allsel                      
lsel,s,loc,z,-30,30
lsel,r,loc,y,-0.25
lsel,r,loc,x,3.5
cm,gj3_2,line
latt,2,4,2
allsel                      
lsel,s,loc,z,-30,30
lsel,r,loc,y,-0.25
lsel,r,loc,x,-3.5
cm,gj3_3,line
latt,2,4,2
allsel                      
lsel,s,loc,z,-30,30
lsel,r,loc,y,-0.25
lsel,r,loc,x,-2.2
cm,gj3_4,line
latt,2,4,2
allsel                       !选择4#块上的钢筋
lsel,s,loc,z,-40,40
lsel,r,loc,y,-0.25
lsel,r,loc,x,1.95
cm,gj4_1,line
latt,2,5,2
allsel                     
lsel,s,loc,z,-40,40
lsel,r,loc,y,-0.25
lsel,r,loc,x,3.75
cm,gj4_2,line
latt,2,5,2
allsel                     
lsel,s,loc,z,-40,40
lsel,r,loc,y,-0.25
lsel,r,loc,x,-3.75
cm,gj4_3,line
latt,2,5,2
allsel                     
lsel,s,loc,z,-40,40
lsel,r,loc,y,-0.25
lsel,r,loc,x,-1.95
cm,gj4_4,line
latt,2,5,2
allsel


!将各个阶段的钢筋定义成组便于以后分析钢筋内力的变化
cmsel,s,gj1_1
cmsel,a,gj1_2
cmsel,a,gj1_3
cmsel,a,gj1_4
cm,gj1,line
allsel
cmsel,s,gj2_1
cmsel,a,gj2_2
cmsel,a,gj2_3
cmsel,a,gj2_4
cm,gj2,line
allsel
cmsel,s,gj3_1
cmsel,a,gj3_2
cmsel,a,gj3_3
cmsel,a,gj3_4
cm,gj3,line
allsel      
cmsel,s,gj4_1
cmsel,a,gj4_2
cmsel,a,gj4_3
cmsel,a,gj4_4
cm,gj4,line
allsel
lsel,s,,,gj1
lsel,a,,,gj2
lsel,a,,,gj3
lsel,a,,,gj4
esize,1                 !划分钢筋单元,每1m一段
lmesh,all
allsel
vmesh,all                !划分所有体单元
nummrg,all
numcmp,all

                        !0号块的全部单元
nsel,s,loc,z,-1,1
esln,s,1,all
cm,kuai0,elem
allsel
                        !1号块的全部单元
nsel,s,loc,z,-10,-1
nsel,a,loc,z,10,1
esln,s,1,all
cm,kuai1,elem
allsel
                         !2号块的全部单元
nsel,s,loc,z,-20,-10
nsel,a,loc,z,20,10
esln,s,1,all
cm,kuai2,elem
allsel
                         !3号块的全部单元
nsel,s,loc,z,-30,-20
nsel,a,loc,z,30,20
esln,s,1,all
cm,kuai3,elem
allsel
                         !4号块的全部单元
nsel,s,loc,z,-30,-40
nsel,a,loc,z,30,40
esln,s,1,all
cm,kuai4,elem
allsel

nsel,s,loc,y,-14.5        !将墩底所有节点约束
d,all,all
allsel
finish


/config,noeldbw,1
/solu
!阶段1只有0#块
time,1
eqslv,pcg
nsubst,2
nlgeom,on
nropt,full
estif,1e-5               !指定矩阵的系数(为杀死的单元所设)
allsel
ekill,all
esel,s,,,kuai0
ealive,all
nsle,s
nsel,inve                !选择所有不活动的节点
d,all,all,0              !将所有不活动的节点进行约束
allsel
nsel,s,loc,y,-14.5       !选择墩底所有节点
d,all,all                !约束墩底所有节点
allsel
solve
save

!阶段2有0#和1#块
time,2
nsubst,2
allsel
esel,s,,,kuai1
ealive,all
allsel
ddele,all,all
esel,s,live
nsle,s
nsel,inve                !选择所有不活动的节点
d,all,all,0              !将所有不活动的节点进行约束
allsel
nsel,s,loc,y,-14.5       !选择墩底所有节点
d,all,all                !约束墩底所有节点
allsel
solve
save

!阶段3有0#、1#和2#块
time,3
allsel
esel,s,,,kuai2
ealive,all
allsel
ddele,all,all
esel,s,live
nsle,s
nsel,inve                !选择所有不活动的节点
d,all,all,0              !将所有不活动的节点进行约束
allsel
nsel,s,loc,y,-14.5       !选择墩底所有节点
d,all,all                !约束墩底所有节点
allsel
solve
save

!阶段4有0#、1#、2#和3#块
time,4
allsel
esel,s,,,kuai3
ealive,all
allsel
ddele,all,all
esel,s,live
nsle,s
nsel,inve                !选择所有不活动的节点
d,all,all,0              !将所有不活动的节点进行约束
allsel
nsel,s,loc,y,-14.5       !选择墩底所有节点
d,all,all                !约束墩底所有节点
allsel
solve
save

!阶段5有0#、1#、2#、3#和4#块
time,5
allsel
nsel,s,loc,z,-40,40
esln,s,1,all
ealive,all
allsel
ddele,all,all
nsel,s,loc,y,-14.5       !选择墩底所有节点
d,all,all                !约束墩底所有节点
allsel
solve
save


/config,noeldbw,1
/solu
!阶段1只有0号块
time,1
eqslv,pcg               !选择Pcg求解器(为节约机时),以下命令用于模拟施工过程,也就是分批杀死单元
nsubst,2
nlgeom,on               !打开大变形开关
nropt,full               !设置Newton-rapshon选项
estif,1e-5               !指定矩阵的系数(为杀死的单元所设)
allsel
ekill,all               !杀死所有单元
esel,s,,,kuai0
ealive,all              !激活所选单元
nsle,s
nsel,inve                !选择所有不活动的节点
d,all,all,0              !将所有不活动的节点进行约束
allsel
nsel,s,loc,y,-14.5       !选择墩底所有节点
d,all,all                !约束墩底所有节点
allsel
solve
save

!阶段2有0号和1号块
time,2
nsubst,2
allsel
esel,s,,,kuai1
ealive,all
allsel
ddele,all,all            !删除所有节点约束
esel,s,live
nsle,s
nsel,inve                !选择所有不活动的节点
d,all,all,0              !将所有不活动的节点进行约束
allsel
nsel,s,loc,y,-14.5       !选择墩底所有节点
d,all,all                !约束墩底所有节点
allsel
solve
save

!阶段3有0号、1号和2号块
time,3
allsel
esel,s,,,kuai2
ealive,all
allsel
ddele,all,all
esel,s,live
nsle,s
nsel,inve                !选择所有不活动的节点
d,all,all,0              !将所有不活动的节点进行约束
allsel
nsel,s,loc,y,-14.5       !选择墩底所有节点
d,all,all                !约束墩底所有节点
allsel
solve
save

!阶段4有0号、1号、2号和3号块
time,4
allsel
esel,s,,,kuai3
ealive,all
allsel
ddele,all,all
esel,s,live
nsle,s
nsel,inve                !选择所有不活动的节点
d,all,all,0              !将所有不活动的节点进行约束
allsel
nsel,s,loc,y,-14.5       !选择墩底所有节点
d,all,all                !约束墩底所有节点
allsel
solve
save

!阶段5有0号、1号、2号、3号和4号块
time,5
allsel
nsel,s,loc,z,-40,40
esln,s,1,all
ealive,all
allsel
ddele,all,all
nsel,s,loc,y,-14.5       !选择墩底所有节点
d,all,all                !约束墩底所有节点
allsel
solve
save

 

  评论这张
 
阅读(254)| 评论(0)

历史上的今天

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2018